Intro Download and install Frequently Asked Questions Tips and tricks

Homepage







© J.C. Kessels 2009
MyDefrag Forum
October 30, 2014, 07:11:08 pm *
Welcome, Guest. Please login or register.

Login with username, password and session length
News:
 
   Home   Help Search Login Register  
Pages: [1] 2 3 ... 25
  Print  
Author Topic: [Script] Jaspion System Disk Optimization v8.1  (Read 82077 times)
Jaspion
JkDefrag Hero
*****
Posts: 238



View Profile WWW
« on: May 12, 2012, 08:43:34 pm »

NEWSFLASH!
Coming up!
Jaspion System Scripts version 10!

Bringing many improvements over version 8, and over the "unreleased" version 9!

All are welcome to try the test release! (check here)



Jaspion System Disk Optimization Scripts v8.1 - 1 December 2012

Including Jaspion Data Disk Optimization Scripts v3.3

The Jaspion MyDefrag Scripts are a highly customizable set of scripts aimed at improving overall performance (everyday file reading and writing operations) as well as boot and defragmentation times.

The user can - but doesn't have to - easily and detailedly configure file/directory selection, so acceleration is totally controllable. You can place your games or important applications at the front for best performance. You can push unused files such as backups to the back so they won't have to be moved again, speeding up defragmentation and clearing up fast space to speed up file writing operations.

These scripts are built to be flexible: they can be tailored to give more performance to applications that generate great amounts of data and therefore benefit from more fast free space at the front, or configured for best reading performance on drives that have little data being written to. The default settings are designed to work well with any PC.

The Jaspion Scripts are mainly folder-based, which has two big advantages: 1) your files (especially the spacehogs) won't dance around the disc as they do with access-date-based scripts, thus ensuring your program and system data is always at a fast position: more performance with less data shuffling. 2) Media files are placed according to their folder location, not by filetype: many programs have media files such as .jpg or .avi files that are loaded with and used by the binary files, and the folder-based placement strategy of the Jaspion Scripts will ensure all program files, binary or not, are put together, thus accelerating the programs (only those files found in exclusively media folders are pushed to slower positions).

These are just some of the features of the Jaspion Scripts. You can find more information below and in the ReadMe file included with the scripts. Download links are found at the bottom of this post.

Enjoy!


---

Many thanks go to Jeroen Kessels for creating MyDefrag. I would also like to thank Darlis for his great contribution. Rohk, woodfold, antonyfrn, deLeewit, peptobismal and Julien have also helped improve the Jaspion Scripts, not to mention other Forum members whose posts have helped me develop the Jaspion scripts.

---


##########
# How to use #
##########

Simply unpack the scripts to the Scripts folder of your MyDefrag installation. If you have a previous version installed, remove all old files before installing the new version. If you have edited your CONFIGFILEs or variables, you'll have to pass on the alterations to the new files.

It is important to disable the built-in Windows Defragmenter so it won't interfere with MyDefrag.

Note: the contents of the "Documents and Settings" and "User" folders are placed alongside program and system files since many programs use them to store data. The default media folders within them are excluded by the "CONFIGFILE - System and Program Files Exclusion List.txt". The Windows "Documents" and "My Documents" folders are not excluded from acceleration by default because they are also used for program data storage. If you have spacehogs in these folders, it is recommended to exclude them in an appropriate folder via the aforementioned CONFIGFILE. One easy way is to use folders named "My Work" or "User Files" inside the Windows default Documents folder.


####################
# System Disk Optimization #
####################

Main features:

- Priority Zone: the user may select files to be placed first.

- Last-place Zone: the user may select files to be placed last. These files will be processed first and placed at the end of the disk. Best used with very large, rarely-used files only, so they will never have to be moved again.

- 12 Levels of defragmentation: 8 Levels + 4 Fast Levels. Fast Levels do not process the MFT and special NTFS files to diminish drive wear and defrag times.

- Folder-based organization. More user control, stability and speed.

- txt CONFIGFILEs to easily set configurations across all Levels. The user can easily control which files are placed in each zone, and achieve great control and performance.

- Exclusion list: the user may select files to be ignored.

- Preset and configurable management of e-mail databases, fonts, etc.

- Larger files are placed further back, thus improving seek times. This functionality, like many others, may be altered or disabled. As default, spacehogs are moved to the end of the disk to improve subsequent defragmentation times.

- Configurable variables via "System Disk Variables.MyD".


File layout and respective processing order:

  Note:
            * = configurable via corresponding CONFIGFILE.
          ** = configurable via "System Disk Variables.MyD".

End of the disk:
  Optional last-place files*.
    (These are processed first in order to place very large files
     out of the way where they won't have to be moved again.)
System files position**:
  Directories.
  MFT and some other special NTFS files.
    (The predefined SystemFilesPosition is 12.5% of the VolumeUsed,
     in order to speed up system, programs and writing of new files.)
Beginning of the disk:
  Font files*.
  Boot, prefetch, registry and log files.
  Optional priority files*.
  Small recently modified system and program files*/**.
    (In lower Levels boot, prefetch, registry and log files are grouped
       into one Zone for faster processing. In higher Levels these files
       are sorted separately.)
Create a small gap**:
    (Via SmallGap variable. Default is 1% of VolumeSize.)
  Remaining system and program files*/**.
Create a large gap**:
    (Via LargeGap variable. Default is 10% of VolumeSize.)
  Remaining files smaller than a determined size*/**.
Optionally create a complemental gap*/**.
    (Via OptionalGap variable. Default is 5% of VolumeSize.)
  All remaining files.



##################
# Data Disk Optimization #
##################

Main features:

- Folder-based organization.

- 7 Levels of defragmentation: 6 Levels + 1 Fast Level. Fast Levels do not process the MFT and special NTFS files to diminish drive wear and defrag times.

- txt CONFIGFILEs to easily set configurations across all Levels.

- Priority Zone: the user may select files to be placed first.

- Last-place Zone: the user may select files to be placed last. These files will be processed first and placed at the end of the disk. Best used with very large, rarely-used files only.

- Exclusion list: the user may select files to be ignored.

- Larger files are placed further back, thus improving seek times. This functionality may be altered or disabled.

- Configurable variables via "Data Disk Variables.MyD".

File layout and respective processing order:

  Note: *  = configurable via corresponding CONFIGFILE.
        ** = configurable via "Data Disk Variables.MyD".

End of the disk:
  Optional last-place files*.
      (These are processed first in order to place very large files
       out of the way where they won't have to be moved again.)
System files position**:
  Directories.
  MFT and some other special NTFS files.
      (The predefined SystemFilesPosition is 25% of the VolumeUsed.
       This parameter may be changed via "Data Disk Variables.MyD".)
Beginning of the disk:
  Optional priority files*.
  Remaining files smaller than a determined size**.
  All remaining files.


Example script:

Code:
##############################
#  Jaspion MyDefrag Scripts  #
##############################

#  System Disk Optimization v8.1 2012-11-29
#  compatible with MyDefrag v4.3.0 and 4.3.1

Title('System Disk Optimization - Level 8')
Description('This script performs a thorough system disk optimization for
trimonthly to semestral usage. FILE SORTING: all system and program files /
optional priority files / remaining relevant files. FREE SPACE CONSOLIDATION:
good.')

# Load the variables from the 'System Disk Variables.MyD' script.
RunScript('System Disk Variables.MyD')

# Load the exclusion list to prevent certain files from being processed.
!include "CONFIGFILE - Global Exclusion List.txt"!

/* Write the header to the logfile. See the 'Settings.MyD' file for the
   definition of the 'LogHeader' string. */
WriteLogfile('!ScriptTitle!.log','LogHeader')

/* Select and process the system volume. */
VolumeSelect
  CommandlineVolumes()
VolumeActions

  /* Write the 'before' statistics to the logfile. See the 'Settings.MyD' file
     for the definition of the 'LogBefore' string. */
  AppendLogfile('!ScriptTitle!.log','LogBefore')

  /* Run the variables script again to update volume dependant values. */
  RunScript('System Disk Variables.MyD')

  /* Zone 1 - Place files at the end of the disk. */
  FileSelect
    !include "CONFIGFILE - Last-place Files.txt"!
  FileActions
    MoveToEndOfDisk()
  FileEnd

  /* Place files at a determined position on the disk. */
  MakeGap(RoundUp(SystemFilesPosition,RoundSystemFilesPosition), DoNotVacate)

  /* Zone 2 - Directories, and a gap. */
  FileSelect
    Directory(yes)
  FileActions
    SortByName(Ascending)
    AddGap(RoundUp(ZoneEnd + 8MB,32MB), DoNotVacate)
  FileEnd
 
  /* Zone 3 - MFT and some other special NTFS files, and a gap. */
  FileSelect
    SelectNtfsSystemFiles(yes)
  FileActions
    PlaceNtfsSystemFiles(Ascending,MftSize * 0.1)
  FileEnd

  /* Place files at the beginning of the disk. */
  MakeGap(0)

  /* Zone 4 - Font files. */
  FileSelect
    !include "CONFIGFILE - Font Files.txt"!
  FileActions
    SortByName(Ascending)
  FileEnd

  /* Zone 5 - Registry and log files. */
  FileSelect
    DirectoryPath("?:\Windows\System32\Config")
      or FileName("ntuser*")
      or FileName("UsrClass*")
      or FileName("*.log*")
  FileActions
    SortByName(Ascending)
  FileEnd

  /* Zone 6 - Boot files. */
  FileSelect
    ImportListFromBootOptimize()
        and not(!include "CONFIGFILE - Boot and Prefetch Exclusion List.txt"!)
  FileActions
    SortByImportSequence(Ascending)
  FileEnd

  /* Zone 7 - Prefetch files. */
  FileSelect
    ImportListFromProgramHints("*.pf")
        and not(!include "CONFIGFILE - Boot and Prefetch Exclusion List.txt"!)
  FileActions
    SortByImportSequence(Ascending)
  FileEnd

  /* Zone 8 - Priority files. */
  FileSelect
    !include "CONFIGFILE - Priority Files.txt"!
  FileActions
    SortByName(Ascending)
  FileEnd

  /* Zone 9 - Small and recently modified system and program files, and a gap. */
  FileSelect
    !include "CONFIGFILE - System and Program Files.txt"!
      and LastChange(NumberOfSeconds ago,now)
        and not(!include "CONFIGFILE - E-mail Databases.txt"!
          or !include "CONFIGFILE - System and Program Files Exclusion List.txt"!
          or Size(LargeFileSizeA,0))
  FileActions
    SortByName(Ascending)
    AddGap(RoundDown(Minimum(ZoneEnd + SmallGap, ZoneEnd + VolumeFree * 0.05),RoundGapSize),DoNotVacate)
  FileEnd

  /* Zone 10 - Remaining system and program files. */
  FileSelect
    !include "CONFIGFILE - System and Program Files.txt"!
      and not(!include "CONFIGFILE - System and Program Files Exclusion List.txt"!)
  FileActions
    SortByName(Ascending)
  FileEnd

  /* Create a free space area. */
  MakeGap(RoundDown(Minimum(ZoneBegin + LargeGap, ZoneBegin + VolumeFree * 0.5),RoundGapSize),DoNotVacate)

  /* Zone 11 - Remaining files smaller than a determined size. */
  FileSelect
    Size(0,LargeFileSizeB)
  FileActions
    SortByName(Ascending)
  FileEnd

  /* Create a complemental free space area (optional). */
  !include "CONFIGFILE - Complemental Free Space Area.txt"!

  /* Zone 12 - All remaining files. */
  FileSelect
    all
  FileActions
    !include "CONFIGFILE - Last Zone FileActions.txt"!
  FileEnd

  /* Write the "after" statistics to the logfile. See the "Settings.MyD" file
     for the definition of the "LogAfter" string. */
  AppendLogfile("!ScriptTitle!.log","LogAfter")

VolumeEnd

/* Write the footer to the logfile. See the "Settings.MyD" file for the
   definition of the "LogFooter" string. */
AppendLogfile("!ScriptTitle!.log","LogFooter")



Please let me know of any questions, suggestions, or problems.

Happy optimizing!

Note:
The title of the Thread has been changed many times to reflect current version. The replies made by me and by other Forum members bear the title of the version that was active at the time of writing. Observations about earlier versions may not apply to current version.

Important notes:
The default "Settings.MyD" MyDefrag script will not work, so you must set your exclusions via the "System Disk Variables.MyD" script or via the Exclusion CONFIGFILES.

If you are using an SSD drive, do not use these scripts. Instead use the default MyDefrag Flash memory disks script (in which case you should set your exclusions in the script itself or in the "Settings.MyD" script.)


Note:
The following files have the same content. Most archivers can open 7z. Zip file also available for compatibility.

* Jaspion System Scripts v8.1 and Data Scripts v3.3.7z (9.62 KB - downloaded 2203 times.)
* Jaspion System Scripts v8.1 and Data Scripts v3.3.zip (48.56 KB - downloaded 1526 times.)
« Last Edit: October 19, 2013, 11:32:09 am by Jaspion » Logged

Jaspion Optimization Scripts for System and Data Disks
http://www.mydefrag.com/forum/index.php?topic=5843.0
Darlis
JkDefrag Hero
*****
Posts: 1772


View Profile WWW
« Reply #1 on: May 13, 2012, 10:30:29 am »

Interesting modifications. Allow me to make some remarks:
  • You're not using my variables script but you're still using the variable "logfileName" for the logfile name. This results in a logfile named "!logfileName!".
  • In your post, you've quoted me to replace the automatic scripts too, but there are no automatic scripts in your collection to replace them with.
  • Placing MFT and directories at the beginning of the volume (like it was done in the old system disk scripts) is a step backwards in performance.
  • You're not excluding the e-mail DBs from the boot zone. They're likely to be selected and placed in this zone.
  • You're not using sorting actions for the boot and program files. That may result in less file movement but it will also reduce performance.
  • Moving files to the end of the volume has two disadvantages, imho: It's wasting fast space and, considering that HDDs with less than 500GB capacity are becoming rare, the seek times would increase drastically. It's similar with placing the e-mail DBs at 60%.
    Also note that Windows likes to place new files where there are currently some I/O operations going on. So new files will likely end up at the end of the volume if files at this position are accessed.
  • The level 1 script basically only defragments files but doesn't move them (all) to their zones. Especially because of the behavior described above, files will stay  (and keep being) scattered around the disk.
  • And finally some nitpicking: You're code isn't well formatted Wink
Logged

Need help creating a script? Try MyDefrag Script Creator.
Jaspion
JkDefrag Hero
*****
Posts: 238



View Profile WWW
« Reply #2 on: May 13, 2012, 05:25:06 pm »

Hi Darlis!

Thank you very much for your input! I am currently working on your suggestions, but first I have a few notes and questions.

The Level 1 script won't move all files to their zones you say. I thought a MoveUpToZone would have that effect. The purpose of Level 1 (I shall include a more detailed description in the next version) is really to just quickly defragment all your files without any free space consolidation. Will I need a FastFill, or is there something else I can do to place files in their correct zones? If not, maybe this level should remain like this, for, as I said, its objective is to just quickly ensure you have no fragmented files. This may be useful if you have a new installation for example, and you want it defragged quickly for the moment, and do a more thorough optimization later. It's really a script for when you have little time to defrag.

Also, that's the objective of not sorting boot and program files. I reckon performance is more affected by disk position (and being close together) than by sorting. So the lower levels are meant to work faster but give less performance. Maybe I shall add one or two upper levels to the scripts to add the sorting options.

About files at the end of the disk. This is maybe the most controversial setting for defraggers. I am among those who like this option, and I'll state my opinion on the matter. Perhaps the solution later will be to develop two different script sets, so the user can choose which strategy to use. I like the media files at the end of my disk (as well as downloaded files, backups, archives, etc) because I believe this minimizes data movement. I tend to let my disks grow quite a bit, with such downloads as videos, new programs, etc. So when, for example, I have a new installation in my programs folder, and it takes up enough space so RoundUp won't prevent movement of the next zone, there will be a lot of file movement to adequate the gap between programs and media. The same will happen again if you decide to uninstall the aforementioned program. To me, personally, watching videos or listening to music or opening zip files that are at the end of the disk does not signify a big loss in performance, and I prefer them at the end of the disk because it's a more definitive position than "?GB" after programs and thus prevents unnecessary file movement. This is aimed both at achieving faster defrags and prolonging the life span of the drive. However, especially if you have few such media and download files in your computer, you may see very little advantage in this strategy. So, like I said, maybe two sets of scripts with different strategies will solve this.

About the MFT and directories at the beginning of the disk: I didn't know it would badly affect performance. Why is that, I wonder.

All your other suggestions will be passed on to the new scripts (with also the missing auto scripts). Hopefully we can develop a better script after all this. Thank you very much!!!
Logged

Jaspion Optimization Scripts for System and Data Disks
http://www.mydefrag.com/forum/index.php?topic=5843.0
Darlis
JkDefrag Hero
*****
Posts: 1772


View Profile WWW
« Reply #3 on: May 13, 2012, 05:57:46 pm »

The Level 1 script won't move all files to their zones you say. I thought a MoveUpToZone would have that effect.
MoveUpToZone only moves file upwards (from beginning to end of the volume). You need FastFill to move files above the zone downwards.

The purpose of Level 1 (I shall include a more detailed description in the next version) is really to just quickly defragment all your files without any free space consolidation.
Then it highly depends on the current file layout. Like if the files of one program are scattered around the disk a simple defragment won't help much because of the high seek times. Also lots of gaps will create more new fragmented files.

Also, that's the objective of not sorting boot and program files. I reckon performance is more affected by disk position (and being close together) than by sorting.
An HDD is fastest when it reads sequentially. If the files are placed in the order they are accessed, then the HDD can ideally read these as one big chunk.

This is aimed both at achieving faster defrags and prolonging the life span of the drive. However, especially if you have few such media and download files in your computer, you may see very little advantage in this strategy.
Actually, I do have a lot of media files and do some downloading and recording. I first these media files at the end of the volume too, but then I noticed that new files where all scattered around the disk because I was accessing both files at the beginning and end of the volume. These files don't need much performance, yes, but it involves a lot of head movement which definitely does not benefit the lifespan of the disk.

About the MFT and directories at the beginning of the disk: I didn't know it would badly affect performance. Why is that, I wonder.
This is because of the seek times. The MFT is often being read from and written to, the farther away the file in question is, the farther the head has to move back and forth. Usually, the boot files are at the beginning of the volume, hence they profit most from being directly next to the MFT. Of course, any other (more regularly used, and especially newly created) files are being disadvantaged.
Logged

Need help creating a script? Try MyDefrag Script Creator.
Jaspion
JkDefrag Hero
*****
Posts: 238



View Profile WWW
« Reply #4 on: May 16, 2012, 04:03:58 am »

Hi Darlis!

Quote
You're not using my variables script but you're still using the variable "logfileName" for the logfile name. This results in a logfile named "!logfileName!".
Fixed. Now log points to MyDefrag.log

Quote
In your post, you've quoted me to replace the automatic scripts too, but there are no automatic scripts in your collection to replace them with.
Automatic scripts will be added soon.

Quote
Placing MFT and directories at the beginning of the volume (like it was done in the old system disk scripts) is a step backwards in performance.
These files are now placed at 30% into the data on the disk. Darlis, your scripts place these files at 2GB into the disk, right? Isn't that almost the same as placing them at the very beginning? Your explanation about the seek times was very good, and helped me understand this issue. However, I believe your strategy is hardly any different from what mine was, and when I was thinking about the best way to place these files, I came up with the idea that turned up being what the default script already does.

Quote
You're not excluding the e-mail DBs from the boot zone. They're likely to be selected and placed in this zone.
Right, fixed.

Quote
You're not using sorting actions for the boot and program files. That may result in less file movement but it will also reduce performance.
Fixed.

Quote
Moving files to the end of the volume has two disadvantages, imho: It's wasting fast space and, considering that HDDs with less than 500GB capacity are becoming rare, the seek times would increase drastically. It's similar with placing the e-mail DBs at 60%.
Also note that Windows likes to place new files where there are currently some I/O operations going on. So new files will likely end up at the end of the volume if files at this position are accessed.
Fixed. I have dropped the move-to-end-of-disk strategy.

Quote
The level 1 script basically only defragments files but doesn't move them (all) to their zones. Especially because of the behavior described above, files will stay  (and keep being) scattered around the disk.
Fixed.

Quote
And finally some nitpicking: You're code isn't well formatted
True  Grin. Fixed.

Quote
An HDD is fastest when it reads sequentially. If the files are placed in the order they are accessed, then the HDD can ideally read these as one big chunk.
Fixed.


The scripts are in version 2.3b (version 1 should have been called a beta as well). I have tested them and they seem to be working well so far.

Darlis thank you very much for your help!
Logged

Jaspion Optimization Scripts for System and Data Disks
http://www.mydefrag.com/forum/index.php?topic=5843.0
Rohk
JkDefrag Hero
*****
Posts: 165



View Profile
« Reply #5 on: May 16, 2012, 11:39:54 am »

Interesting script. I too have firefox and thunderbird profiles in my layout.ini file.

Why are these there including some other files (like spotify data which can be over 1gb..) that I sure now are not used in windows boot at all? Would these not be included if I change the prefetching parameter to prefetch only boot files?

Another idea about the move to the end of the disk. Would it be good idea to move files that has not been accessed let's say last 6 months ago to the end of the disk? I believe this would speed up future defrags and hardly files that hasn't been accessed that long would then be accessed in near future either.

One more thing I think the best location for the temp files zone would be after the "fast and stable zones" as it would then reduce the file movement between defragment jobs. And temp files are scattered around the disk afterwards, anyway.

And yeah, please include one version in code tags! would make it easier to see the script and compare the future changes! Smiley
Logged
Jaspion
JkDefrag Hero
*****
Posts: 238



View Profile WWW
« Reply #6 on: May 16, 2012, 06:02:49 pm »

Why are these there including some other files (like spotify data which can be over 1gb..) that I sure now are not used in windows boot at all? Would these not be included if I change the prefetching parameter to prefetch only boot files?

One more thing I think the best location for the temp files zone would be after the "fast and stable zones" as it would then reduce the file movement between defragment jobs. And temp files are scattered around the disk afterwards, anyway.

I'm not sure which zone you are referring to. Zone 3 has the boot files, Zone 4 is prefetch files, and Zone 6 is program & windows files. Zone 5 is temporary files, and comes before the program files to get them out of the way, and place them in a faster zone (you may need them at next reboot, for instance). Placing them after the programs would slow down Zone 5 considerably. But Zone 5 being rather small compared to Zone 6, placing it in this order affects Zone 6's performance negligibly.

About Windows files that are not often used: I place them along with the programs because I want my system fast at all times. Same with programs. Even if it's a program that's not often used, I want it accelerated as much as possible so whenever I need those files they'll be fast. Also, "Windows", starting with W, will come after the programs in a SortByName, thus you won't have the bloat of the Windows folder taking up faster disk space -- they will be fast, but program files will be faster. And the Windows files that are always necessary will be already even faster in preceding zones.


Another idea about the move to the end of the disk. Would it be good idea to move files that has not been accessed let's say last 6 months ago to the end of the disk? I believe this would speed up future defrags and hardly files that hasn't been accessed that long would then be accessed in near future either.

I think it wouldn't. As Darlis put it:

Moving files to the end of the volume has two disadvantages, imho: It's wasting fast space and, considering that HDDs with less than 500GB capacity are becoming rare, the seek times would increase drastically. It's similar with placing the e-mail DBs at 60%. Also note that Windows likes to place new files where there are currently some I/O operations going on. So new files will likely end up at the end of the volume if files at this position are accessed.

And:

Actually, I do have a lot of media files and do some downloading and recording. I first these media files at the end of the volume too, but then I noticed that new files where all scattered around the disk because I was accessing both files at the beginning and end of the volume. These files don't need much performance, yes, but it involves a lot of head movement which definitely does not benefit the lifespan of the disk.

Placing files at the end of the disk does not improve overall performance. And in reality it does little to reduce defrag times, if anything at all!

I thought about such a strategy as well, of only placing very old files at the end of the disk. But what if you need to open the file just once? That will generate a lot of file movement at the next defrag. And at the one 6 months (or so) from now. And meanwhile the file will be taking up precious space up front. So I say no to date-based defrag.

And I say no to placing files near the end of the disk. Those files will be unnecessarily slow, and new files will be much more likely to be scattered around the disk. Head movement will be increased, reducing the drive's lifespan and increasing seek times, so it's an overall loss in performance. I came a long way from being a fan of this strategy, but now I realise it won't do you much good.

Perhaps I would make only one exception, and I might put this one to the test briefly and come back with the results. That is when you have a very large file, say a 20GB 7z archive, that won't be changed. If you include only such very large unchanging files at the end of the disk, and instruct MyDefrag to place them there and exclude them from future defrags, it might save you a lot of file movement when preceding zones grow. Scattered creation of new files may remain a problem, but with the reduced number of files at the end of the disk, scattering may not be so terrible in this case.

And yeah, please include one version in code tags! would make it easier to see the script and compare the future changes! Smiley
Like this?
Code:
/* Place files at 30% into the data on the disk. */
  MakeGap(RoundUp(VolumeUsed * 0.3,VolumeSize * 0.01), DoNotVacate)

  /* Zone 1: Directories. */
  FileSelect
    Directory(yes)
  FileActions
    Defragment()
    MoveUpToZone()
    FastFill(WithShuffling)
    AddGap(RoundUp(ZoneEnd, 10M))
  FileEnd
 
  /* Zone 2: Place the MFT and some other special NTFS files. */
  FileSelect
    SelectNtfsSystemFiles(yes)
  FileActions
    Defragment()
    MoveUpToZone()
    FastFill(WithShuffling)
  FileEnd
Logged

Jaspion Optimization Scripts for System and Data Disks
http://www.mydefrag.com/forum/index.php?topic=5843.0
Darlis
JkDefrag Hero
*****
Posts: 1772


View Profile WWW
« Reply #7 on: May 16, 2012, 06:35:35 pm »

These files are now placed at 30% into the data on the disk. Darlis, your scripts place these files at 2GB into the disk, right? Isn't that almost the same as placing them at the very beginning?
These files are placed at a fixed position to reduce file movement on the next defrag. That position is quiet close to the beginning, yes, but it should be way after the boot files and next to gaps between zone 3, 4 and 5 where new files can be created. Most parts of the MFT are probably already loaded into the file cache, so accessing a file far away from the MFT might not require a physical read of the MFT (and directories).
I've created a separate variables script just for reasons like this, where you can simply change the location of the MFT in all 6 scripts (manual and automatic) by editing just one line.

Interesting script. I too have firefox and thunderbird profiles in my layout.ini file.
The layout.ini file contains all files listed in the Prefetch files. If you've set the parameter to 3 (boot and programs, the default) it will contain both boot and program files (with the boot files always listed first).
So the description "files used when booting" or the name of the ImportListFromBootOptimize() file select is a bit misleading here.

Zone 4, the Prefetch files, only contains those files that are not included in the layout.ini. The list is usually updated every 3 days whereas the Prefetch files are on every program start.
Logged

Need help creating a script? Try MyDefrag Script Creator.
Rohk
JkDefrag Hero
*****
Posts: 165



View Profile
« Reply #8 on: May 16, 2012, 07:55:17 pm »

I'm not sure which zone you are referring to.
To the Zone 6. But as you said it might lead to disk with less performance over little more stability.

Also tested the MoveEndOfTheDisk() idea to my data disk and file last access date 6 months. The performance of it was just horrible for small files, so I set it to only move files bigger than 100mb. After that I noticed it moved one of my movies that I just never had watched yet, so no time stamp or it was over from 6 months. nevertheless it's rather pointless idea to use without knowing the files which to move. Only reason if the disk is over 80% full or so..

One more question about file actions sequence. What is the right or the best way to use:

MoveUpToZone()
Defragment()
FastFill()

OR

Defragment()
MoveUpToZone()
FastFill()

On manual it reads that MoveUpToZone() already defrags files when they are moved up to the zone. Wouldn't it be ideal to use defragment after it?
Logged
Darlis
JkDefrag Hero
*****
Posts: 1772


View Profile WWW
« Reply #9 on: May 16, 2012, 08:50:52 pm »

The first version might be the better one: MoveUpToZone also clears the zone from any non-selected files so the subsequent Defragment action could ideally place the defragmented file at the right position without FastFill having to move it again.
Logged

Need help creating a script? Try MyDefrag Script Creator.
woodfold
JkDefrag Senior
****
Posts: 31


View Profile
« Reply #10 on: May 17, 2012, 12:26:06 am »

Are these supposed to be run individually, or one after another? Are they like Monthly, Weekly, Daily?

Please explain.
Logged
Jaspion
JkDefrag Hero
*****
Posts: 238



View Profile WWW
« Reply #11 on: May 17, 2012, 12:58:09 am »

These files are now placed at 30% into the data on the disk. Darlis, your scripts place these files at 2GB into the disk, right? Isn't that almost the same as placing them at the very beginning?
These files are placed at a fixed position to reduce file movement on the next defrag. That position is quiet close to the beginning, yes, but it should be way after the boot files and next to gaps between zone 3, 4 and 5 where new files can be created. Most parts of the MFT are probably already loaded into the file cache, so accessing a file far away from the MFT might not require a physical read of the MFT (and directories).

But what about head movement / seek times for the rest of your files? 2GB into the disk is the same as at the very beginning, so only files close to the beginning of the disk will benefit, thus not the bulk of the files, thus slowing down overall performance.


I've created a separate variables script just for reasons like this, where you can simply change the location of the MFT in all 6 scripts (manual and automatic) by editing just one line.
Yes! Indeed it is a clever solution! I will look to implement it! Thanks!

The first version might be the better one: MoveUpToZone also clears the zone from any non-selected files so the subsequent Defragment action could ideally place the defragmented file at the right position without FastFill having to move it again.
It makes a lot of sense! I'm testing this and apparently Darlis is right again. Will be implemented in next version.

Are these supposed to be run individually, or one after another? Are they like Monthly, Weekly, Daily?

Please explain.

Yes, they can be used like that. Level 1 is equivalent to a Daily defrag. Level 2 equivalent to a Weekly defrag. And Level 3 a Monthly defrag. A clearer indication of that will be in the next version as well.

Next version fixing these issues will be available soon under the name 2.4b.
Logged

Jaspion Optimization Scripts for System and Data Disks
http://www.mydefrag.com/forum/index.php?topic=5843.0
Darlis
JkDefrag Hero
*****
Posts: 1772


View Profile WWW
« Reply #12 on: May 17, 2012, 01:18:25 pm »

But what about head movement / seek times for the rest of your files? 2GB into the disk is the same as at the very beginning, so only files close to the beginning of the disk will benefit, thus not the bulk of the files, thus slowing down overall performance.
Yes, I've answered that already. The word "optimizied" in my scripts means "less file movement" not "more performance". Maybe I'll move them further inside in the volume in the next version.
Logged

Need help creating a script? Try MyDefrag Script Creator.
Jaspion
JkDefrag Hero
*****
Posts: 238



View Profile WWW
« Reply #13 on: May 22, 2012, 04:24:12 pm »

Jaspion's Optimize System Disk Scripts Version 3 available!

Users of version 2.X should update to this version!

Automatic scripts now included!!

See first post for updated description / scripts.
Logged

Jaspion Optimization Scripts for System and Data Disks
http://www.mydefrag.com/forum/index.php?topic=5843.0
Jaspion
JkDefrag Hero
*****
Posts: 238



View Profile WWW
« Reply #14 on: May 22, 2012, 10:35:38 pm »

Second release out!

Small improvements and new level of Automatic added.

Corrected: Automatic Script Level 4 was wrongly labelled as Level 3.

See 1st post for more info & files.
« Last Edit: May 22, 2012, 10:46:57 pm by Jaspion » Logged

Jaspion Optimization Scripts for System and Data Disks
http://www.mydefrag.com/forum/index.php?topic=5843.0
Pages: [1] 2 3 ... 25
  Print  
 
Jump to:  

Powered by MySQL Powered by PHP Powered by SMF 1.1.5 | SMF © 2006-2008, Simple Machines LLC Valid XHTML 1.0! Valid CSS!