Script Request-SWTOR

[antonyfrn]

Hi was wondering if anyone out there can come up with a script for TOR as it has some slow loading times and would love to keep the game at the start of the HDD plus im not realy sure what im doing with making scripts. or if anyone can point me to a good guide for making them thats idiot proof. (currently use he optimised daily scripts posted on these forums)

what i would want todo is this

------Drive Start-----
D:\Games\Star Wars-The Old Republic
D:\Games\Star Wars-The Old Republic\ --everything else
D:\Games\Steam
D:\Games\Steam\steamapps\common\ --steam games in order of most played

[Darlis]

D:\Games\Star Wars-The Old Republic
D:\Games\Star Wars-The Old Republic\ --everything else

I'm not sure how you want the files to be organized. At first, you want all files in D:\Games\Star Wars-The Old Republic but not the subdirectories and then the files int the subdirectories?

There are some posts about how to organize Steam games like this one: Scripts for Steam software and games.

[antonyfrn]

Well i would like to have all of the SWTOR data stored at the start of the drive in hopes of improving the horrific load times. but im not totaly fussed about how the other data is stored so i probably need a modified data script for daily weekly and monthly ive tried using that GUI tool for scripts and its made me give up still to complicated for me (TBH MyDefrag could do with a realy dumb down way of making scripts seeing im not a coder of any sorts)

[Darlis]

You can edit the data script and put the following code just before zone 3:

Code:

  /* Zone 2.5: SWTOR files. */
  FileSelect
    DirectoryPath("D:\Games\Star Wars-The Old Republic")
  FileActions
    ...
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd

Replace "..." with the file actions from zone 3 (they are different in each script).

I wonder where you got stuck with my Script Creator. Some feedback would help me improve it.

[antonyfrn]

well the script creator i just didnt understand it at all i tried importing scripts in it to have a look how it worked and didnt understand it at all what would be nice is a step by step tutorial form the basics to advanced thing it

[antonyfrn]

Oh and thanks its working  all very nicely waiting on a monthly run to complete plus its given me some ideas on how to place things on my HDD how i want them eg most used games to help with load times

[Darlis]

I'm working on a guide but I currently have no time to do so. There is a small How To that covers the basics.
The import function is not the best one, it often switches to Advanced or even Custom Mode, making it hard for beginners. You can download the MyDefrag standard scripts from here and take look at those.

[Wolfmight]

I tried making special scripts to move entire game directories to the beginning of a disk seperate from the system disk and found no real noticeable improvements.  HOWEVER, running defraggler to remove all fragments+MFT fragments, then running MyDefrag's "Data Disk Monthly" script seems to definitely reduce stuttering in games.  I do this every month for peek performance of hard disks. 

"Defrag Only" before the Monthly script to reduce the fragments after a "Data Disk Monthly"
Running "System Disk Monthly" on a drive with only games will pull data further from the beginning with more free space gaps and technically provide slower performance.  Hence the name "System Disk Monthly"  it's only meant for the system disk. 

What also helps A LOT is making sure there's atleast around 50% free space.   

[Darlis]

I tried making special scripts to move entire game directories to the beginning of a disk seperate from the system disk and found no real noticeable improvements.  HOWEVER, running defraggler to remove all fragments+MFT fragments, then running MyDefrag's "Data Disk Monthly" script seems to definitely reduce stuttering in games.

Since the Monthly scripts moves and defragments every file, there is no point in running any other script or defragmenter beforehand.

[antonyfrn]

Just posting my scripts for my game drives in hopes to get some feedback and tips for any improvements.

Daily

Code:

Title('Game Disk Daily')
Description("Modiffied Data Disk Daily description")   // See the "Settings.MyD" file.

/* Write the header to the logfile. See the "Settings.MyD" file for the
   definition of the "LogHeader" string. */
WriteLogfile("MyDefrag.log","LogHeader")

/* Select and process the volumes one by one. */
VolumeSelect
  CommandlineVolumes()
VolumeActions

  /* Write the "before" statistics to the logfile. See the "Settings.MyD" file
     for the definition of the "LogBefore" string. */
  AppendLogfile("MyDefrag.log","LogBefore")

  /* Zone 1: Place the MFT and some other special NTFS files. */
  FileSelect
    SelectNtfsSystemFiles(yes)
  FileActions
    PlaceNtfsSystemFiles(Ascending,MftSize * 0.01)
  FileEnd

  /* Zone 2: Directories. */
  FileSelect
    Directory(yes)
  FileActions
    FastFill()
  FileEnd

  MakeGap(RoundUp(ZoneBegin,VolumeSize * 0.001))

  /* Zone 2.1: SWTOR files. */
  FileSelect
    DirectoryPath("D:\Games\Star Wars-The Old Republic")
  FileActions
    Defragment(Fast)
    FastFill()
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd

  /* Zone 2.2: total war shogun 2 files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\total war shogun 2")
  FileActions
    Defragment(Fast)
    FastFill()
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 2.3: The Witcher 2 files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\the witcher 2")
  FileActions
    Defragment(Fast)
    FastFill()
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 2.4: Dead island files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\dead island")
  FileActions
    Defragment(Fast)
    FastFill()
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 2.5: L.A Noire files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\l.a.noire")
  FileActions
    Defragment(Fast)
    FastFill()
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 2.6: Portal 2 files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\portal 2")
  FileActions
    Defragment(Fast)
    FastFill()
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 3: all other files. */
  FileSelect
    all
  FileActions
    Defragment(Fast)
    FastFill()
  FileEnd

  /* Write the "after" statistics to the logfile. See the "Settings.MyD" file
     for the definition of the "LogAfter" string. */
  AppendLogfile("MyDefrag.log","LogAfter")

VolumeEnd

/* Write the footer to the logfile. See the "Settings.MyD" file for the
   definition of the "LogFooter" string. */
AppendLogfile("MyDefrag.log","LogFooter")

Weekly

Code:

Title('Game Disk Weekly')
Description("Modiffied Data Disk Weekly description")   // See the "Settings.MyD" file.



/* Write the header to the logfile. See the "Settings.MyD" file for the
   definition of the "LogHeader" string. */
WriteLogfile("MyDefrag.log","LogHeader")

/* Select and process the volumes one by one. */
VolumeSelect
  CommandlineVolumes()
VolumeActions

  /* Write the "before" statistics to the logfile. See the "Settings.MyD" file
     for the definition of the "LogBefore" string. */
  AppendLogfile("MyDefrag.log","LogBefore")

  /* Zone 1: Place the MFT and some other special NTFS files. */
  FileSelect
    SelectNtfsSystemFiles(yes)
  FileActions
    PlaceNtfsSystemFiles(Ascending,MftSize * 0.01)
  FileEnd

  /* Zone 2: Directories. */
  FileSelect
    Directory(yes)
  FileActions
    SortByName(Ascending)
  FileEnd

  MakeGap(RoundUp(ZoneBegin,VolumeSize * 0.001))

  /* Zone 2.1: SWTOR files. */
  FileSelect
    DirectoryPath("D:\Games\Star Wars-The Old Republic")
  FileActions
    Defragment(Fast)
    Defragment()
    FastFill(WithShuffling)
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd

  /* Zone 2.2: total war shogun 2 files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\total war shogun 2")
  FileActions
    Defragment(Fast)
    Defragment()
    FastFill(WithShuffling)
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 2.3: The Witcher 2 files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\the witcher 2")
  FileActions
    Defragment(Fast)
    Defragment()
    FastFill(WithShuffling)
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 2.4: Dead island files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\dead island")
  FileActions
    Defragment(Fast)
    Defragment()
    FastFill(WithShuffling)
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 2.5: L.A Noire files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\l.a.noire")
  FileActions
    Defragment(Fast)
    Defragment()
    FastFill(WithShuffling)
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 2.6: Portal 2 files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\portal 2")
  FileActions
    Defragment(Fast)
    Defragment()
    FastFill(WithShuffling)
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd

  /* Zone 3: all other files. */
  FileSelect
    all
  FileActions
    Defragment(Fast)
    Defragment()
    FastFill(WithShuffling)
  FileEnd

  /* Write the "after" statistics to the logfile. See the "Settings.MyD" file
     for the definition of the "LogAfter" string. */
  AppendLogfile("MyDefrag.log","LogAfter")

VolumeEnd

/* Write the footer to the logfile. See the "Settings.MyD" file for the
   definition of the "LogFooter" string. */
AppendLogfile("MyDefrag.log","LogFooter")

Montly

Code:

Title('Game Disk Monthly')
Description("Modiffied Data Disk Monthly description")   // See the "Settings.MyD" file.



/* Write the header to the logfile. See the "Settings.MyD" file for the
   definition of the "LogHeader" string. */
WriteLogfile("MyDefrag.log","LogHeader")

/* Select and process the volumes one by one. */
VolumeSelect
  CommandlineVolumes()
VolumeActions

  /* Write the "before" statistics to the logfile. See the "Settings.MyD" file
     for the definition of the "LogBefore" string. */
  AppendLogfile("MyDefrag.log","LogBefore")

  /* Zone 1: Place the MFT and some other special NTFS files. */
  FileSelect
    SelectNtfsSystemFiles(yes)
  FileActions
    PlaceNtfsSystemFiles(Ascending,MftSize * 0.01)
  FileEnd

  /* Zone 2: Directories. */
  FileSelect
    Directory(yes)
  FileActions
    SortByName(Ascending)
  FileEnd

  MakeGap(RoundUp(ZoneBegin,VolumeSize * 0.001))

  /* Zone 2.1: SWTOR files. */
  FileSelect
    DirectoryPath("D:\Games\Star Wars-The Old Republic")
  FileActions
SortByName(Ascending)
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 2.2: total war shogun 2 files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\total war shogun 2")
  FileActions
SortByName(Ascending)
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 2.3: The Witcher 2 files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\the witcher 2")
  FileActions
SortByName(Ascending)
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 2.4: Dead island files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\dead island")
  FileActions
SortByName(Ascending)
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 2.5: L.A Noire files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\l.a.noire")
  FileActions
SortByName(Ascending)
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 2.6: Portal 2 files. */
  FileSelect
    DirectoryPath("D:\Games\Steam\steamapps\common\portal 2")
  FileActions
SortByName(Ascending)
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd
 
  /* Zone 3: all other files. */
  FileSelect
    all
  FileActions
    SortByName(Ascending)
  FileEnd

  /* Write the "after" statistics to the logfile. See the "Settings.MyD" file
     for the definition of the "LogAfter" string. */
  AppendLogfile("MyDefrag.log","LogAfter")

VolumeEnd

/* Write the footer to the logfile. See the "Settings.MyD" file for the
   definition of the "LogFooter" string. */
AppendLogfile("MyDefrag.log","LogFooter")

What i would like to try and do is dump directorys like the ones listed below at the end of the disk as they are not ever used.

D:\Games\Star Wars-The Old Republic\EUALAs
D:\Games\Star Wars-The Old Republic\extras
D:\Games\Star Wars-The Old Republic\readmes
D:\Games\Steam\steamapps\common\total war shogun 2\redist
D:\Games\Steam\steamapps\common\the witcher 2\redist
D:\Games\Steam\steamapps\common\batman2\Setup (not added to script yet)
D:\Games\Steam\steamapps\common\dead island\Redist
D:\Games\Steam\steamapps\common\l.a.noire\reslists

[Darlis]

What i would like to try and do is dump directorys like the ones listed below at the end of the disk as they are not ever used.

Place the following zone between zone 2 and 2.1:

Code:

  FileSelect
    DirectoryPath("D:\Games\Star Wars-The Old Republic\EUALAs")
    or DirectoryPath("D:\Games\Star Wars-The Old Republic\extras")
    or ...
  FileActions
    MoveToEndOfDisk()
  FileEnd

You may want to consider to exclude save and log files from the games folder since these like to change often and a new sorting action would take unnecessarily longer.

[antonyfrn]

just looking over the steam script gave me a idea would this work

Code:

  /* Zone : SWTOR. */
  FileSelect
    DirectoryPath("D:\Games\Star Wars-The Old Republic")
and not(
      or directoryname("EUALAs")
      or directoryname("extras")
      or directoryname("readmes")
  )
  FileActions
    Defragment(Fast)
    FastFill()
    AddGap(RoundUp(ZoneBegin,VolumeSize * 0.01))
  FileEnd

[Darlis]

Remove the first "or", then it's a valid script.
It will move the 3 directories (in whichever directory they may reside) behind the SWTOR zone and, if no other zone includes these files, they will be moved behind all other zones.

[Rohk]

One problem that occured for me with script like this was that I were too lazy to change the game paths to the script as I install and uninstall games..

I tried to make my "steam scripts" as universal as possible and keep the original data scripts behavior. It gets the job done for me by placing the game files that I currently play to the beginning of the disk as I have it scheduled to run it weekly and daily I use it with the mydefrag screen saver. Monthly script I hardly ever use because of my laziness..

The idea of it was to,
* place steam program files first as I always launch steam
* second game files accessed past "x" days (I currently use 14 days but to get more stable disk use month or more. If you use sorting then it is compromise between time it takes.)
* third rest of the game files and last all other files (for time saving now one single zone)

This I currently use (monthly), hopefully you get some ideas to your own scripts:

Code:

/* Select drive E: */
VolumeSelect
  Name("E:")
VolumeActions

  /* Zone 1: Place the MFT and some other special NTFS files. */
  FileSelect
    SelectNtfsSystemFiles(yes)
  FileActions
    PlaceNtfsSystemFiles(Ascending,MftSize * 0.01)
  FileEnd

  /* Zone 2: Directories. */
  FileSelect
    Directory(yes)
  FileActions
    SortByName(Ascending)
  FileEnd

  /* Zone 3: Steam program files and no old cache files nor game files. */
  FileSelect
    DirectoryName("Steam")
    and not(
      (LastAccessEnabled(yes) and LastAccess(,14 days ago))
      or DirectoryName("steamapps")
      or DirectoryName("Backup")
      or DirectoryName("dumps")
      or DirectoryName("old")
      )
  FileActions
    Defragment(Fast)
    Defragment()
    MoveUpToZone()
    FastFill(WithShuffling)
    AddGap(RoundUp(ZoneEnd,VolumeSize * 0.001), DoNotVacate)
  FileEnd

  /* Zone 4: Game files, accessed last 2 weeks and smaller than 1gb
      and no setups nor save games. */
  FileSelect
    DirectoryName("steamapps")
    or DirectoryName("Games")
      and not(
    (LastAccessEnabled(yes) and LastAccess(,14 days ago))
    or size (1gb,0)
    or directoryname("directx")
    or directoryname("dotnet")
    or directoryname("*install*")
    or directoryname("redist")
    or directoryname("redistributable")
    or directoryname("save*")
    or directoryname("support")
    or directoryname("temp")
    or filename("*.cab")
    or filename("*.gcf")
    or filename("*.ncf")
    or filename("*inst*.exe")
    or filename("*Physx*.exe")
    or filename("*setup*.exe")
    or filename("*vcredist*.exe")
    )
  FileActions
    SortByName(Ascending)
  FileEnd
 
  /* Zone 5: Big game files, Steam ".gcf" and ".ncf" files and savegames, and a gab. */
  FileSelect
    DirectoryName("steamapps")
    or DirectoryName("Games")
      and not(
    (LastAccessEnabled(yes) and LastAccess(,14 days ago))
    or directoryname("directx")
    or directoryname("dotnet")
    or directoryname("*install*")
    or directoryname("redist")
    or directoryname("redistributable")
    or directoryname("support")
    or directoryname("temp")
    or filename("*.cab")
    or filename("*inst*.exe")
    or filename("*Physx*.exe")
    or filename("*setup*.exe")
    or filename("*vcredist*.exe")
    )
  FileActions
    Defragment(Fast)
    Defragment()
    FastFill(WithShuffling)
    AddGap(RoundUp(ZoneEnd + Minimum(VolumeUsed * 0.05, VolumeFree * 0.05),VolumeSize * 0.001))
  FileEnd
 
  /* Zone 6: remaining files. */
  FileSelect
    all
  FileActions
    Defragment(Fast)
    FastFill()
  FileEnd

VolumeEnd

[Talven81]

I was just looking to do this EXACT thing with SWTOR. Thank you everyone!

With the 1.2 update log files are going to become cumbersome so I made mine slightly different.

Code:

FileSelect
    DirectoryPath("C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic\EUALAs")
    or DirectoryPath("C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic\extras")
or DirectoryPath("C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic\readmes")
or DirectoryPath("C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic\locales")
or DirectoryPath("C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic\logs")
  FileActions
    MoveToEndOfDisk()
  FileEnd

  /* Zone 2.5: SWTOR files. */
  FileSelect
    DirectoryPath("C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic")
and not(
directoryname("EUALAs")
or directoryname("extras")
or directoryname("readmes")
or directoryname("locales")
or directoryname("logs")
)

  FileActions
    SortByImportSequence(Ascending)
    AddGap(RoundUp(ZoneEnd,VolumeFree * 0.01))
  FileEnd