New feature for the drive map.

The SetPalette command, combined with FileSelect to describe which files you wish to work with, can do this.

Here is my version of AnalyzeOnly.MyD, which uses different colors for various stuff. I wasn't focusing on directories, so I used a rather invisible color for them, but you can change the SetPalette commands. The three numbers are red, green, blue, from 0 to 255.

# MyDefrag v4.0 default script: Analyze only
#
# This script is part of the standard MyDefrag distribution.

Title('Analyze only')
Description('
Analyze all the fixed, mounted, writable disks on the computer. The script
will automatically pause between disks, so the user can view and interpret
the diskmap.
')

RunScript('Settings')
WhenFinished(exit)

SetPalette(allocated=0,0,104)      # dark-blue
SetPalette(unmovable=104,104,104)   # gray

VolumeSelect
CommandlineVolumes()
and Removable(no)
and Writable(yes)
and Mounted(yes)
VolumeActions

#---------------------------------------------------------------
SetPalette(unfragmented=64,96,64)   # dark-gray-green
SetPalette(fragmented=96,64,64)   # dark-gray-red
FileSelect
ImportListFromBootOptimize()   # --- boot ---
FileActions
FileEnd

#---------------------------------------------------------------
SetPalette(unfragmented=224,224,0)   # yellow
SetPalette(fragmented=224,224,0)   # yellow
FileSelect
FileName("$mft")         # --- $MFT ---
FileActions
FileEnd

#---------------------------------------------------------------
SetPalette(unfragmented=255,128,255) # light-purple
SetPalette(fragmented=255,96,192)   # light-purple-red
FileSelect
Directory(yes)         # --- directory ---
FileActions
FileEnd

#---------------------------------------------------------------
# ----- Program Files -----
Title('Zone: Program Files')
SetPalette(unfragmented=0,255,255)   # cyan
SetPalette(fragmented=255,0,0)   # red
FileSelect
DirectoryName("Program Files")
FileActions
FileEnd

#---------------------------------------------------------------
# ----- Windows -----
Title('Zone: Windows')
SetPalette(unfragmented=255,208,64)   # yellow-orange
SetPalette(fragmented=255,0,0)   # red
FileSelect
DirectoryName("Windows")
FileActions
FileEnd

#---------------------------------------------------------------
# ----- not space hogs -----
SetPalette(unfragmented=64,200,64)   # green
SetPalette(fragmented=255,0,0)   # red

FileSelect
not(
Size(50000000,0)
or (LastAccessEnabled(yes) and LastAccess("","1 month ago"))
or DirectoryName("$RECYCLE.BIN")
or DirectoryName("RECYCLED")
or DirectoryName("RECYCLER")
or DirectoryName("$*")
or DirectoryName("Downloaded Installations")
or DirectoryName("Ehome")
or DirectoryName("Fonts")
or DirectoryName("Help")
or DirectoryName("I386")
or DirectoryName("IME")
or DirectoryName("Installer")
or DirectoryName("ServicePackFiles")
or DirectoryName("SoftwareDistribution")
or DirectoryName("Speech")
or DirectoryName("Symbols")
or DirectoryName("ie7updates")
or DirectoryName("dllcache")
or DirectoryName("Installshield Installation Information")
or DirectoryName("System Volume Information")
or DirectoryName("windows.old")
or FileName("*.7z")
or FileName("*.arj")
or FileName("*.avi")
or FileName("*.bak")
or FileName("*.bup")
or FileName("*.bz2")
or FileName("*.cab")
or FileName("*.chm")
or FileName("*.dvr-ms")
or FileName("*.gz")
or FileName("*.ifo")
or FileName("*.log")
or FileName("*.lzh")
or FileName("*.mp3")
or FileName("*.msi")
or FileName("*.old")
or FileName("*.pdf")
or FileName("*.rar")
or FileName("*.rpm")
or FileName("*.tar")
or FileName("*.wav")
or FileName("*.wmv")
or FileName("*.vob")
or FileName("*.z")
or FileName("*.zip")
)
FileActions
FileEnd

#---------------------------------------------------------------
# ----- Space Hogs -----
SetPalette(unfragmented=64,64,96)   # dark-gray-blue
SetPalette(fragmented=128,0,0)   # medium red
FileSelect
all
FileActions
FileEnd

Pause("")

VolumeEnd