[DO NOT RUN THIS SCRIPT UNLESS YOU WANT SWTOR TO BE THE FASTEST THING ON YOUR DRIVEDO NOT RUN THIS SCRIPT ON A SOLID STATE DRIVE]

I found this old post, and my old post and thought an update might be in order. I have created a MyDefrag script for my SWTOR guild. This script does several things...

DO NOT RUN THIS SCRIPT UNLESS YOU WANT SWTOR TO BE THE FASTEST THING ON YOUR DRIVE
DO NOT RUN THIS SCRIPT ON A SOLID STATE DRIVE (Currently working on an SSD version, much less is necesary)

1. Place most critical files and directory structure at the beginning of the disk. (Zone 1 and 2)
2. Move scrap files (.tmp, .bak, .log, readmes, etc.) to the end of the drive and out of the way. (Zone 3)
3. Make SWTOR the first program on the drive for maximum speed. (Zone 4)
4. Now place boot files, we want boot to be fast, but after boot we rarely need to access. (Zone 5)
5. Place most frequently accessed programs. (Zone 6)
6. Place all normal files. (Zone 7)
7. Place all space-hog files. (Zone

THE FIRST TIME THIS SCRIPT IS RUN IT WILL TAKE A LONG TIME - RECOMMENDED TO BE RUN AFTER EVERY SWTOR PATCH TO MINIMIZE TIME

Code:

# MyDefrag v4.0 default script: System Disk Monthly
#
# This script is part of the standard MyDefrag distribution.

Title('SWTOR Post Patch Defrag')
Description("System Disk Monthly description")      // See the "Settings.MyD" file.



/* Write the header to the logfile. See the "Settings.MyD" file for the
   definition of the "LogHeader" string. */
WriteLogfile("MyDefrag.log","LogHeader")

/* Select and process the volumes one by one. */
VolumeSelect
  CommandlineVolumes()
VolumeActions

  /* Write the "before" statistics to the logfile. See the "Settings.MyD" file
     for the definition of the "LogBefore" string. */
  AppendLogfile("MyDefrag.log","LogBefore")

  /* Place files at 30% into the data on the disk. */
  MakeGap(RoundUp(VolumeUsed * 0.3,VolumeSize * 0.01), DoNotVacate)

  /* Zone 1: Place the MFT and some other special NTFS files. */
  FileSelect
    SelectNtfsSystemFiles(yes)
  FileActions
    PlaceNtfsSystemFiles(Ascending,MftSize * 0.1)
  FileEnd

  /* Zone 2: Directories. */
  FileSelect
    Directory(yes)
  FileActions
    SortByName(Ascending)
  FileEnd

  /* Place files at the beginning of the disk. */
  MakeGap(0)

  /* Zone 3: Move Scrap Files and Files with Constant Change To Harmless Area */
  FileSelect
    DirectoryName("EUALAs")
or DirectoryName("readmes")
or DirectoryName("reademe")
or DirectoryName("logs")
or DirectoryName("Firestorm")
or DirectoryName("Temporary Internet Files")
or DirectoryName("$RECYCLE.BIN")
    or DirectoryName("RECYCLED")
    or DirectoryName("RECYCLER")
or FileName("ReadMe*.*")
or FileName("*.log")
or FileName("*.tmp")
or FileName("*.old")
or FileName("*.bak")
  FileActions
    MoveToEndOfDisk()
  FileEnd

  /* Zone 4: SWTOR files. */
  FileSelect
    DirectoryName("Star Wars-The Old Republic")
  FileActions
    SortByName(Ascending)
    AddGap(RoundUp(ZoneEnd,VolumeFree * 0.01))
  FileEnd
 
  /* Zone 5: files used when booting, and a gap. */
  FileSelect
    ImportListFromBootOptimize()
  FileActions
    SortByImportSequence(Ascending)
    AddGap(RoundUp(ZoneEnd,VolumeFree * 0.01))
  FileEnd

 
  /* Zone 6: files used by the most used programs, and a gap. */
  FileSelect
    ImportListFromProgramHints("*.pf")
  FileActions
    SortByImportSequence(Ascending)
    AddGap(RoundUp(ZoneEnd,VolumeFree * 0.01))
  FileEnd

 
 
  /* Zone 7: regular files and a gap. */
  FileSelect
    not(
      Size(50000000,0)
      or (LastAccessEnabled(yes) and LastAccess(,1 month ago))
      or DirectoryName("$*")
      or DirectoryName("Downloaded Installations")
      or DirectoryName("Ehome")
      or DirectoryName("Fonts")
      or DirectoryName("Help")
      or DirectoryName("I386")
      or DirectoryName("IME")
      or DirectoryName("Installer")
      or DirectoryName("ServicePackFiles")
      or DirectoryName("SoftwareDistribution")
      or DirectoryName("Speech")
      or DirectoryName("Symbols")
      or DirectoryName("ie?updates")
      or DirectoryName("dllcache")
      or DirectoryName("Installshield Installation Information")
      or DirectoryName("System Volume Information")
      or DirectoryName("windows.old")
      or FileName("*.7z")
      or FileName("*.arj")
      or FileName("*.avi")
      or FileName("*.bup")
      or FileName("*.bz2")
      or FileName("*.cab")
      or FileName("*.chm")
      or FileName("*.dvr-ms")
      or FileName("*.gz")
      or FileName("*.ifo")
      or FileName("*.iso")
      or FileName("*.lzh")
      or FileName("*.mp3")
      or FileName("*.msi")
      or FileName("*.pdf")
      or FileName("*.rar")
      or FileName("*.rpm")
      or FileName("*.tar")
      or FileName("*.wav")
      or FileName("*.wmv")
      or FileName("*.vob")
      or FileName("*.z")
      or FileName("*.zip")
      )
  FileActions
    SortByName(Ascending)
    AddGap(RoundUp(ZoneEnd,VolumeFree * 0.01))
  FileEnd

  /* Zone 8: spacehog files (less important files that take up a lot of space). */
  FileSelect
    all
  FileActions
    SortByName(Ascending)
  FileEnd

  /* Write the "after" statistics to the logfile. See the "Settings.MyD" file
     for the definition of the "LogAfter" string. */
  AppendLogfile("MyDefrag.log","LogAfter")

VolumeEnd

/* Write the footer to the logfile. See the "Settings.MyD" file for the
   definition of the "LogFooter" string. */
AppendLogfile("MyDefrag.log","LogFooter")

I was just looking to do this EXACT thing with SWTOR. Thank you everyone!

With the 1.2 update log files are going to become cumbersome so I made mine slightly different.

Code:

FileSelect
    DirectoryPath("C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic\EUALAs")
    or DirectoryPath("C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic\extras")
or DirectoryPath("C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic\readmes")
or DirectoryPath("C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic\locales")
or DirectoryPath("C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic\logs")
  FileActions
    MoveToEndOfDisk()
  FileEnd

  /* Zone 2.5: SWTOR files. */
  FileSelect
    DirectoryPath("C:\Program Files (x86)\Electronic Arts\BioWare\Star Wars-The Old Republic")
and not(
directoryname("EUALAs")
or directoryname("extras")
or directoryname("readmes")
or directoryname("locales")
or directoryname("logs")
)

  FileActions
    SortByImportSequence(Ascending)
    AddGap(RoundUp(ZoneEnd,VolumeFree * 0.01))
  FileEnd